プログラミング実践:第02回(String/Imageクラス)
Categories:
型
Processingでは,変数は必ず「型」を持ちます.
これまで,
int,
float,
boolean,
color
などの比較的単純な型や,複数のデータをまとめて扱う
配列 などを使ってきました.
- プリミティブ型
int x;
float y = 3.14;
boolean flag = true;
比較的単純です.
- 配列
int[] numbers = new int[10];
color[] colors = new color[10];
プリミティブ型をまとめて扱えます.
Processingでは,これら以外にも,より複雑なデータを扱うための型があります.今回は,その中でもデータと機能をまとめて扱うことができる クラス について学んでいきます.
参考: Processing/Reference/Structure/class
クラス
クラスとは, 変数(フィールド) と 関数(メソッド) がまとまった複合データ型のことです.
すべてのクラスは クラス名 を持ち,必要に応じて フィールド(データ) , コンストラクタ , メソッド が含まれます.
クラスについての詳細は第4回以降のオブジェクト指向プログラミングについての講義で学びます.
クラスは自分で作ることもできますが,Processingには,あらかじめさまざまなクラスが用意されています.
たとえば,以下のようなクラスがあります.
- String
- PImage
- ArrayList
- PVector
- …
クラスの仕組みや,自分でクラスを作る方法については,第4回以降のオブジェクト指向プログラミングの講義で詳しく学びます.
今回は,まずProcessingに用意されているクラスを実際に使いながら,クラスの基本的な使い方を学びます.
Stringクラス
参考
String型で扱える値
どのような値を格納できるのかを紹介します.
String s1 = "Hello World";
println(s1);
これだけでも実はとっても便利です.
何が便利かというと,もしString型がなければ,同じように出力するために,たとえば char型 を使って以下のように書く必要があるのです.
char characters[] = {'H','e','l','l','o',' ','W','o','r','l','d'};
for(int i=0; i<11; i++){
print(characters[i]);
}
このように, String には文字をまとめて格納できます.
Stringのメソッド
クラスはメソッドを通じて様々な機能を持ちます.
Stringクラスのメソッドは次のようなものがあります.
length() - 文字数を返す
例
String s1 = "Hello";
println(s1.length());
5
charAt(n) - n文字目の文字を返す
例
String s1 = "Hello";
println(s1.charAt(1));
e
indexOf(文字列) - 文字列が何文字目に登場するかを返す
例
文字列内で最初に登場する位置を出力します.
String s1 = "Hello World";
println(s1.indexOf("o"));
4
String s1 = "Hell World Hello";
println(s1.indexOf("Hello"));
11
indexOf(文字列, n) - n文字目以降で文字列が何文字目に登場するかを返す
例
String s1 = "Hello World";
println(s1.indexOf("o", 5));
7
substring(n) - n文字目から最後までを出力
例
String s1 = "Hello World";
println(s1.substring(6));
World
substring(x, y) - x文字目からy-1文字目までを出力
例
String s1 = "Hello World";
println(s1.substring(0, 5));
Hello
toLowerCase(文字列) - 全てを小文字に変換
例
String s1 = "Hello WORLD";
println(s1.toLowerCase());
hello world
toUpperCase(文字列) - 全てを大文字に変換
例
String s1 = "Hello World";
println(s1.toUpperCase());
HELLO WORLD
replace(文字列x, 文字列y) - 文字列xを文字列yに変更
例
String s1 = "Hello World";
println(s1.replace("World", "Processing"));
Hello Processing
split(区切り文字) - 文字列を分割
例
String s1 = "apple,banana,orange";
String[] fruits = s1.split(",");
println(fruits[0]);
println(fruits[1]);
println(fruits[2]);
apple
banana
orange
concat(文字列) - 文字列を連結
例
String s1 = "Hello";
String s2 = s1.concat(" World");
println(s2);
Hello World
equals(文字列) - 2つの文字列が等しいかを判定
例
String s1 = "Hello";
String s2 = "Hello";
String s3 = "World";
println(s1.equals(s2));
println(s1.equals(s3));
true
false
String: 練習問題
文字列
Action is the foundational key
を String 型の変数 str1 に格納してください.
str1 に対して,次の操作を行ってください.
-
"f"が最初に現れるインデックスをコンソールに表示してください.(注意: インデックスは
0から始まります.) -
str1の文字数をコンソールに表示してください. -
str1を半角スペース (" ") で分割し,最初の単語Actionのみをコンソールに表示してください. -
str1の末尾にto all success.をつなげ,新しい文字列をString型の変数str2に格納してください. -
str2に含まれる"."を"!"に置き換えて,コンソールに表示してください. -
str2のアルファベットをすべて大文字に変換して,コンソールに表示してください.
14
30
Action
Action is the foundational key to all success.
Action is the foundational key to all success!
ACTION IS THE FOUNDATIONAL KEY TO ALL SUCCESS.
PImageクラス
参考
PImage型で扱える値
PImageクラスは画像を扱うためのクラスです.
まず,演習で使用する画像を以下からダウンロードしてください.
(保存済みの) Processing のスケッチにダウンロードした画像を追加します.
このとき,画像を保存する場所に注意してください.
スケッチフォルダ内に data フォルダを作成し,その中に画像ファイルを保存します.
あるいは,Processing上に画像ファイルをドラッグ&ドロップすると, data フォルダが自動的に作成され,その中に画像ファイルが追加されます.
画像を追加したあとのファイル構成は,たとえば次のようになります. (スケッチ名やファイル名は各自の環境によって異なります.)
flower_display/
├── flower_display.pde
└── data/
└── flower.png
まず,画像を読み込んで表示してみます.
- loadImage() : PImage型の変数を返す関数.dataフォルダを探してくれます.
- image() : 画像を描画する関数.
image(画像(PImage型), x座標, y座標)もしくはimage(画像(PImage型), x座標, y座標, width, height)のように使用できます.
PImage img;
void setup(){
size(800, 800);
img = loadImage("flower.png");
image(img, 0, 0);
}
キャンパスサイズ(800,800)に比べて画像が大きかったので,画像の大きさを調整してみます.
PImage img;
void setup(){
size(800, 800);
img = loadImage("flower.png");
image(img, 0, 0, 200, 200);
}
PImageのフィールド
PImageには,フィールドを通じて画像に関する様々なデータが格納されています.
例として、次のようなものが挙げられます。
width:画像の横幅height:画像の高さ- pixels[] : 画像を構成する各ピクセルの色
フィールドは次のようにして使用できます.
変数名.フィールド名
たとえば,
img.width
img.height
とすると, img が持っている横幅と高さを取り出すことができます.
width - 画像の横幅
例
PImage img;
void setup(){
img = loadImage("flower.png");
println(img.width);
}
1254
height - 画像の高さ
例
PImage img;
void setup(){
img = loadImage("test1.png");
println(img.height);
}
1254
pixels[] - 画像を構成するピクセルの色
このフィールドを扱う際は,まず loadPixels() を実行して画像をピクセル単位で扱えるようにします.
loadPixels() を実行すると,画像を構成する各ピクセルの色情報を pixels 配列から参照できるようになります.
例
PImage img;
void setup(){
size(800,800);
img = loadImage("flower.png");
img.loadPixels();
println(img.pixels[0]);
color c = img.pixels[0];
println(red(c));
println(green(c));
println(blue(c));
}
4681804
71.0
112.0
76.0
pixels 配列に格納されている色情報は,RGBの値がそのまま別々に保存されているわけではなく,赤・緑・青などの色情報をまとめた32bitの整数(例では4681804)として扱われます.
RGBの各成分を個別に扱いたい場合は,red(),green(),blue() などの関数を使って,それぞれの値を取り出すことができます.
-
注意
loadPixels()では,出力を一次元配列で受け取ることに注意してください.
PImageのメソッド
PImageクラスには,画像を操作するための様々なメソッドがあります.
resize(w,h) - 画像をリサイズ
画像のサイズを指定したピクセル幅 w と高さ h に変更します. w, h は int 型です.
いずれかのパラメータに 0 を指定すると,元の画像の縦横比を保ったまま大きさを変更できます.
例
PImage img;
void setup(){
size(400, 400);
img = loadImage("flower.png");
img.resize(300, 100);
image(img, 0, 0);
}
get(x, y) - ピクセル座標の色を取得
画像の指定したピクセル座標 (x, y) の色を取得できます.返される値は color 型です.
例
PImage img;
void setup(){
size(600, 600);
img = loadImage("flower.png");
color c = img.get(300, 300);
background(c);
}
get(x, y, w, h) - 画像の一部分を新しい画像として取り出す
get() を使って,画像の指定した矩形領域だけを新しいPImageとして取り出すことができます.
例
PImage img;
PImage part;
void setup(){
size(600, 600);
img = loadImage("flower.png");
part = img.get(200, 200, 300, 300);
image(part, 0, 0);
}
引数の意味は以下の通りです:
x:取り出す領域の左上のピクセルx座標y:取り出す領域の左上のピクセルy座標w:取り出す領域の横幅(ピクセル)h:取り出す領域の高さ(ピクセル)
filter(GRAY) - 画像をグレースケールに変換
画像の色をグレースケール(白黒)に変換します.
例
PImage img;
void setup(){
size(600, 600);
img = loadImage("flower.png");
img.filter(GRAY);
image(img, 0, 0, 500, 500);
}
filter(INVERT) - 画像の色を反転
画像の色を反転(ネガティブ)します.各ピクセルのRGB値が反転されます.
例
PImage img;
void setup(){
size(600, 600);
img = loadImage("flower.png");
img.filter(INVERT);
image(img, 0, 0, 500, 500);
}
filter(BLUR, n) - 画像をぼかす
画像にブラー(ぼかし)効果を適用します.パラメータ n でぼかしの強度を指定します(値が大きいほどぼかしが強くなります).
例
PImage img;
void setup(){
size(600, 600);
img = loadImage("flower.png");
img.filter(BLUR, 5);
image(img, 0, 0, 500, 500);
}
PImage: 練習問題
好きな画像(ファイル形式 .jpg .tga .png のいずれか)を使用して次の操作を順番に行ってください.
注意:画像の容量が大きすぎると表示に時間がかかったり,表示されなかったりする可能性があります.
-
画像を読み込み,
PImage型の変数imgに格納してください. -
imgの横幅と高さをそれぞれコンソールに表示してください. -
imgを画面の座標(100, 50)に表示してください. -
imgの横幅を400ピクセルに変更してください.このとき,画像の縦横比が変化しないようにしてください. -
変更後の
imgの横幅と高さをコンソールに表示してください.
実行例は, 練習問題 から確認してください.