回答

問題

PVector-発展1 の回答ページです.

回答例

PVector position; // ボールの位置
PVector velocity; // ボールの速度
PVector gravity;  // 重力加速度
float d = 40;     // ボールの直径

void setup() {
  size(500, 500);
  noStroke();

  position = new PVector(100, 50);
  velocity = new PVector(2, 0);
  gravity = new PVector(0, 0.3);
}

void draw() {
  fill(0, 15);
  rect(0, 0, width, height);

  velocity.add(gravity);  // 速度に重力加速度を加える
  position.add(velocity); // 位置に速度を加える

  // 床で跳ね返る
  if (position.y + d/2 > height) {
    position.y = height - d/2; // 床の上に戻す
    velocity.y *= -0.8;          // 向きを反転し,0.8倍にする
  }

  // 左右の壁で跳ね返る
  if (position.x - d/2 < 0 || position.x + d/2 > width) {
    velocity.x *= -1;
  }

  fill(255);
  ellipse(position.x, position.y, d, d);
}

解説

加速度を PVector で表す

gravity = new PVector(0, 0.3);

重力は下向きに一定の大きさで働くので,加速度は下向き(y 方向が正)のベクトルで表します.この値は現実の重力加速度(約 9.8 m/s²)を換算したものではなく,画面上で見やすい動きになるように選んだ値です.

現実の重力加速度に近づけるには

現実の重力加速度 9.8 m/s² に近づけたいときは,次のように単位を決めて換算します.

  • 長さ: 1 m = 100 px(1 px = 1 cm とみなす)
  • 時間: 1 s = 60 フレーム(Processing の標準は 60 フレーム/秒)
$$ 9.8\ \mathrm{m/s^2} = \frac{9.8 \times 100\ \mathrm{px}}{(60\ \mathrm{frame})^2} = \frac{9.8 \times 100}{60 \times 60}\ \mathrm{px/frame^2} \approx 0.272\ \mathrm{px/frame^2} $$
gravity = new PVector(0, 9.8 * 100 / 60 / 60); // 約 0.272

1 m を何 px とみなすかは自由に決められ,この値を変えると gravity の値も変わります.解答例の 0.3 は,およそ 1 m = 110 px に相当します.

速度と位置の更新

velocity.add(gravity);
position.add(velocity);

加速度は速度の時間変化率(速度が1秒間にどれだけ変化するか),速度は位置の時間変化率です.これをコードで表しています.

1行目で速度に加速度を加えます.これにより,速度の y 成分は毎フレーム0.3ずつ増えます. 2行目で更新後の速度を位置に加えます.

速度の x 成分は変化しないので,ボールは横方向には一定の速さで動きます.縦方向の速さだけが変化するため,軌跡は放物線に近い形になります.

床での跳ね返り

if (position.y + d/2 > height) {
  position.y = height - d/2;
  velocity.y *= -0.8;
}

velocity.y *- 0.8 は,速度の y 成分の符号を反転させ,大きさを0.8倍にします.跳ね返るたびに縦方向の速さが小さくなるので,跳ね上がる高さも少しずつ低くなります.

ボールの最後の様子

解答例では,ボールは最終的に床の上でごく小さく上下し続け,完全には止まりません.毎フレーム重力で下向きの速度が加わり,床で反転する,という処理が繰り返されるためです.

発展

以下のようなことを考えるのも面白いかもしれません.

  • 重力加速度や反発係数(0.8)の値を変えると,動きがどう変わるか確かめてみる.
  • ボールを複数にする.
  • 空気抵抗を表すために,毎フレーム速度を少しだけ小さくしてみる.