回答

問題

クラス-基礎4 の回答ページです.

回答例

PImage img;
float w,h;

void setup(){
  size(800,800);
  background(255);
  img = loadImage("flower.png");

  w = img.width;
  h = img.height;
  image(img,0,0,w,h);
}

void draw(){
}


void mousePressed(){
  background(255);
  img.filter(INVERT) ;
  w = w*0.9;
  h = h*0.9;
  image(img,0,0,w,h);
}

解説

色を反転する( filter(INVERT) )

img.filter(INVERT);

INVERT は各ピクセルの色を反転させるフィルターです.たとえば赤 (255, 0, 0) は (0, 255, 255) のシアンになります.

注意点として, filter() は 画像そのものを書き換えます .そのためクリックのたびに反転が繰り返され,奇数回目は反転色,偶数回目は元の色に戻ります.

縦横比を保ったまま縮小する

w = w*0.9;
h = h*0.9;
image(img,0,0,w,h);

image(img, x, y, w, h) は,画像を幅 w ,高さ h に拡大・縮小して描画します.ここで w と h の両方に同じ倍率(0.9)を掛けているので,縦横比は変わりません.片方だけに倍率を掛けると画像が歪んでしまいます.

また, image() で大きさを変えても 元の画像データ( img )は変化しません .縮小後の大きさは変数 w , h に覚えさせておき,クリックのたびに前回の値に 0.9 を掛けることで,段階的に小さくなります.

さらに, background(255) で画面を白で塗りつぶしてから描画しています.これを省くと,前回描いた大きい画像が残ってしまいます.

w , h を float で宣言しているのは,0.9 倍を繰り返しても小数の端数を切り捨てずに計算するためです.

別解

resize() を使う

PImage img;

void setup(){
  size(800,800);
  background(255);
  img = loadImage("flower.png");
  image(img,0,0);
}

void draw(){

}

void mousePressed(){
  background(255);
  img.filter(INVERT);
  img.resize(int(img.width*0.9), int(img.height*0.9));
  image(img,0,0);
}

img.resize(幅, 高さ) は,画像データ自体を指定した大きさに作り直します.回答例の image(img,0,0,w,h) が「描くときだけ縮める」のに対して, resize() は「画像そのものを縮める」点が違いです.

  • 縮小後は img.width , img.height が新しい大きさに更新されるので,変数 w , h を用意しなくてもよい.
  • 引数は整数( int )なので, int() で変換する.小数部分は切り捨てられる.
  • 片方を 0 にすると,もう一方に合わせて縦横比を保って自動で大きさが決まる(例: img.resize(300, 0) ).

注意点

  • resize() は元に戻せません.縮小するたびにピクセル情報が失われるため,後で拡大しても画質は元に戻りません.
  • 何度も繰り返すと,切り捨ての誤差が積み重なり,縦横比が少しずつずれることがあります.
  • 元の大きさを保ちたい場合や,拡大・縮小を繰り返す場合は,回答例のように image(img,x,y,w,h) を使う方が適しています.