回答

問題

クラス-応用3 の回答ページです.

回答例

PImage img;

void setup() {
  size(500, 500);
  img = loadImage("flower.png");
  img.resize(500, 500); // 画面サイズと合わせる

  image(img, 0, 0);

  img.loadPixels();
  noStroke();

  for(int y=0; y<height; y+=20){
    for(int x=0; x<width; x+=20){
      int i = width*y+x;
      color c = img.pixels[i];
      fill(red(c), green(c), blue(c));
      rect(x, y, 20, 20);
    }
  }
}

解説

画像を画面サイズに合わせて読み込む( resize ・ loadPixels )

img = loadImage("flower.png");
img.resize(500, 500);
img.loadPixels();

img.resize(500, 500) で画像の大きさを画面と同じ 500×500 にそろえています.こうすると img.width と width が同じ値になり,画像上の位置と画面上の位置が一対一で対応します.

先に大きさをそろえて画面と画像の座標を一対一に対応させておかないと, pixels の番号から画面上の位置を求められません.そのため, resize() の後に img.loadPixels() を呼んでいます.

画像の大きさを合わせるために, image(img, 500, 500) と書けばよいと思えるかもしれませんが,この書き方では img 自身の大きさや img.pixels の中身は元の画像のままです.

そのため元の画像が 500×500 でなければ, width*y+x で計算した番号が画面上の位置とずれたり,配列の範囲を超えたりしてしまいます.

ピクセルの色を読み込む( pixels )

int i = width*y+x;
color c = img.pixels[i];

img.pixels は画像のピクセルの色を 1次元 の配列で持っています.画像の幅が width (ここでは500)のとき,座標 (x, y) のピクセルは width*y+x 番目に並んでいます.

ここでは width を使っていますが,リサイズして画面と同じ大きさにしているので img.width と同じ値です.

区画ごとに色を取る

for(int y=0; y<height; y+=20){
  for(int x=0; x<width; x+=20){
    // ...
  }
}

for 文で x と y を 20 ずつ増やすと,20×20 の各区画の左上の座標だけを順に調べられます.その座標のピクセルの色を,区画全体の色として使います.

四角形で塗りつぶす

fill(red(c), green(c), blue(c));
rect(x, y, 20, 20);

red(c)=・=green(c)=・=blue(c) は色 c の赤・緑・青の成分を取り出す関数です.それを fill() に渡すことで,その色で塗りつぶします.

なお, c はすでに色( color 型)なので,成分に分けずに fill(c); と書くだけでも同じ結果になります.

rect(x, y, 20, 20) で,左上が (x, y) の 20×20 の四角形を描きます.