回答

問題

クラス-基礎5 の回答ページです.

回答例

PImage img;
float w,h;

void setup(){
  size(400,400);
  background(255);
  img = loadImage("flower.png");

  img.resize(100,100);
}

void draw(){
  int red = int(random(256));
  int green = int(random(256));
  int blue = int(random(256));

  tint(red, green, blue);

  float x = random(width);
  float y = random(height);

  image(img, x, y);
  frameRate(10);
}

解説

色合いを変える( tint )

tint(r, g, b);
image(img, x, y);

tint(r, g, b) の後に描いた画像は,赤・緑・青の値の影響を受けた色で表示されます. r , g , b はそれぞれ 0 から 255 までのランダムな整数です( random(256) は 0 以上 256 未満の小数を返し, int() で小数点以下を切り捨てます). tint() は後から別の tint() を呼ぶまで有効なので,毎回 draw() の中で新しい値を指定しています.

ランダムな位置に表示する

float x = random(width);
float y = random(height);

image(img, x, y);

random(width) は 0 以上 width 未満のランダムな小数を返します.ここでは width は 400 なので, x は 0 〜 400 の範囲になります. y も同様に random(height) で決めます.

random() は呼ぶたびに違う値を返すので, draw() が実行されるたびに画像の表示位置が変わります.

補足:画像が画面からはみ出す

image(img, x, y) の x , y は画像の 左上 の座標です.画像のサイズは 100x100 なので, x や y が 300 を超えると,画像の一部が画面の外にはみ出します.はみ出さないようにしたい場合は,次のように範囲を狭めます.

float x = random(width - img.width);
float y = random(height - img.height);

img.width , img.height は画像の幅と高さ( resize 後は 100 )です.

補足:int にしたい場合

random() は float を返します. image() は小数の座標も受け取れるのでそのままで問題ありませんが,整数にしたい場合は int(random(width)) とします.

resize の使い方の注意

img.resize(100,100);       // 正しい
img = img.resize(100,100); // 間違い

resize() は 戻り値のない メソッド( void )で,画像そのものを書き換えます.そのため, img = ... のように代入することはできず,エラーになります.

また, resize() は setup() で1回だけ実行します. draw() の中で毎回実行すると,そのたびに画像が劣化したり,無駄な処理が増えたりします.

表示の速さを決める( frameRate )

frameRate(10);

frameRate(10) で,1秒間に draw() を10回実行するように設定します.