回答
Categories:
問題
クラス-応用2 の回答ページです.
回答例
PImage img;
void setup() {
size(500, 500);
img = loadImage("flower.png");
img.resize(500, 500); // 画面サイズと合わせる
image(img, 0, 0);
img.loadPixels();
noStroke();
for(int y=0; y<height; y+=20){
for(int x=0; x<width; x+=20){
int i = width*y+x;
color c = img.pixels[i];
fill(red(c), green(c), blue(c));
rect(x, y, 20, 20);
}
}
}
解説
画像を画面サイズに合わせて読み込む( resize ・ loadPixels )
img = loadImage("flower.png");
img.resize(500, 500);
img.loadPixels();
img.resize(500, 500) で画像の大きさを画面と同じ 500×500 にそろえています.こうすると img.width と width が同じ値になり,画像上の位置と画面上の位置が一対一で対応します.
ピクセルの色を配列で読み込むのは,リサイズ後の画像に対して行う必要があるため, resize() の後に img.loadPixels() を呼んでいます.
ピクセルの色を読み込む( pixels )
int i = width*y+x;
color c = img.pixels[i];
img.pixels は画像のピクセルの色を 1次元 の配列で持っています.画像の幅が width (ここでは500)のとき,座標 (x, y) のピクセルは width*y+x 番目に並んでいます.
ここでは width を使っていますが,リサイズして画面と同じ大きさにしているので img.width と同じ値です.
区画ごとに色を取る
for(int y=0; y<height; y+=20){
for(int x=0; x<width; x+=20){
// ...
}
}
for 文で x と y を 20 ずつ増やすと,20×20 の各区画の左上の座標だけを順に調べられます.その座標のピクセルの色を,区画全体の色として使います.
四角形で塗りつぶす
fill(red(c), green(c), blue(c));
rect(x, y, 20, 20);
red(c)=・=green(c)=・=blue(c) は色 c の赤・緑・青の成分を取り出す関数です.それを fill() に渡すことで,その色で塗りつぶします.
rect(x, y, 20, 20) で,左上が (x, y) の 20×20 の四角形を描きます. noStroke() で輪郭線を消しているため,区画が隙間なく並んで見えます.
参照するピクセルの範囲
for 文の条件 y<height と x<width により, x と y は 0 以上,画面の高さ・幅未満の値だけをとります.画像の大きさは 500×500 なので,インデックス width*y+x は 0 から 249999 の範囲に収まり,配列の外を参照することはありません.