回答
Categories:
問題
PVector-基礎1 の回答ページです.
回答例
1. PVector を使わない場合
float posX, posY, spX, spY; // 円の位置,速度
int d; // 円の直径
void setup() {
size(500, 500);
noStroke();
// 円の直径をランダムに設定(5~30ピクセル)
d = int(random(5, 31));
// 円全体がキャンバス内に収まる範囲で,初期位置をランダムに設定
posX = random(d / 2.0, width - d / 2.0);
posY = random(d / 2.0, height - d / 2.0);
// 速度をランダムに設定(x方向とy方向)
spX = random(-5, 6);
spY = random(-5, 6);
}
void draw() {
// 半透明の黒い四角形を重ねて,軌跡を残す
fill(0, 15);
rect(0, 0, width, height);
// 位置を速度に基づいて更新
posX += spX;
posY += spY;
// 白い円を描画
fill(255);
ellipse(posX, posY, d, d);
// 円の端が左端か右端に達したら,x方向の速度を反転
if (posX - d / 2 < 0 || posX + d / 2 > width) {
spX *= -1;
}
// 円の端が上端か下端に達したら,y方向の速度を反転
if (posY - d / 2 < 0 || posY + d / 2 > height) {
spY *= -1;
}
}
2. PVector を使う場合
PVector position; // 円の位置
PVector velocity; // 円の速度
int d; // 円の直径
void setup() {
size(500, 500);
noStroke();
d = int(random(5, 31));
position = new PVector(random(d / 2.0, width - d / 2.0), random(d / 2.0, height - d / 2.0));
velocity = new PVector(random(-5, 6), random(-5, 6));
}
void draw() {
fill(0, 15);
rect(0, 0, width, height);
// 位置に速度を加える
position.add(velocity);
fill(255);
ellipse(position.x, position.y, d, d);
if (position.x - d / 2 < 0 || position.x + d / 2 > width) {
velocity.x *= -1;
}
if (position.y - d / 2 < 0 || position.y + d / 2 > height) {
velocity.y *= -1;
}
}
解説
半透明の四角形で軌跡を残す
fill(0, 15);
rect(0, 0, width, height);
fill() の2番目の引数は不透明度(0〜255)です.
background() で毎フレーム画面全体を塗りつぶすと,前のフレームの円は完全に消えます.代わりに不透明度の小さい四角形を重ねると,前のフレームの円は少しずつ暗くなりながら残るため,軌跡のように見えます.
初期位置の範囲
d = random(5, 30);
posX = random(d / 2, width - d / 2);
円の中心が d / 2 より左にあると,円の一部がキャンバスの左にはみ出します.はみ出した状態から始まると,跳ね返りの条件が毎フレーム成り立ち,速度の反転が繰り返されて円が端から離れられなくなることがあります.そこで,先に直径 d を決めてから,円全体がキャンバスに収まる範囲で中心の位置を決めます.
跳ね返りの条件
if (posX - d / 2 < 0 || posX + d / 2 > width) {
spX *= -1;
}
PVector で書き換える
PVector position;
PVector velocity;
posX と posY の2つの変数が position に, spX と spY の2つの変数が velocity にまとまります.
position.add(velocity);
posX + spX; と posY + spY; の2行がこの1行になります.
add() は position 自身の値を書き換えるメソッドです.
跳ね返りの判定では,成分を position.x や velocity.x のように取り出して,1の場合と同じように書けます.