クラス-基礎8-回答

問題

クラス-基礎8 の回答ページです.

回答例

Circle base, body, head; // Circle型の変数を3つ用意する

void setup() {
  size(400, 400);
  noStroke();

  // 下の雪玉
  base = new Circle();
  base.x = 200;
  base.y = 290;
  base.d = 160;

  // 真ん中の雪玉
  body = new Circle();
  body.x = 200;
  body.y = 170;
  body.d = 120;

  // 頭
  head = new Circle();
  head.x = 200;
  head.y = 85;
  head.d = 80;
}

void draw() {
  background(30, 40, 90);   // 夜空

  fill(200, 220, 255);      // 雪の地面
  rect(0, 340, width, 60);

  base.display();
  body.display();
  head.display();
}


// 白い円を表すクラス
class Circle {
  float x, y; // 中心の座標
  float d;    // 直径

  // 円を描く
  void display() {
    fill(255);
    ellipse(x, y, d, d);
  }
}

解説

クラスを定義する( class )

class Circle {
  float x, y; // 中心の座標
  float d;    // 直径

  void display() {
    fill(255);
    ellipse(x, y, d, d);
  }
}

クラスは,ものの「設計図」です. Circle クラスには,円が持つ情報(フィールド)と,円ができること(メソッド)をまとめて書きます.

  • float x, y; と float d; が フィールド です.クラスの中,メソッドの外で宣言した変数のことです.
  • display() が メソッド です.これまで使ってきた setup() や draw() と同じ書き方で,クラスの中に書きます.

メソッドの中では,フィールドの x , y , d を,そのまま変数として使えます.

インスタンスを作る( new )

Circle base, body, head;

void setup() {
  base = new Circle();
  body = new Circle();
  head = new Circle();
}

Circle base, body, head; で, Circle 型の変数を3つ用意します.この時点では,まだ円は作られていません. new Circle() で,設計図から実際の円(インスタンス)が1つ作られます.

3つの円は,同じ設計図から作られていますが,それぞれが自分の x , y , d を持っています.

フィールドに値を入れる

base.x = 200;
base.y = 290;
base.d = 160;

変数名のあとに . (ドット)とフィールド名を書くと,そのインスタンスのフィールドを使えます. base.d = 160; は,「 base の直径を160にする」という意味です. body.d や head.d とは別の値です.

メソッドを呼ぶ

base.display();
body.display();
head.display();

メソッドも,ドットをつけて呼びます. base.display() では, base のフィールド( x = 200 , y = 290 , d = 160 )を使って円が描かれます. 同じ display() でも, head.display() では head のフィールドが使われるので,別の円が描かれます.

描く順番

下から順に( base , body , head )描いています.円は重なっても,あとから描いたものが上に描かれます. 地面の rect() を先に描いているので,雪だるまが地面の上に立っているように見えます.

挑戦してみよう

  • 目や鼻をつけるには,クラスの display() に書く方法と, draw() に直接書く方法があります.雪だるまが2体いるとき,どちらが楽か考えてみましょう.
  • 2体目の雪だるまは,クラスを書き換えずに作れます.同じ設計図から,新しい円を3つ作って,値を入れるだけです.